Personal tools

Enumerator and iteratee

From HaskellWiki

(Difference between revisions)
Jump to: navigation, search
(See also: Added a link to "A tutorial on the enumerator library")
Line 90: Line 90:
* John Lato's cabalized [ package] of Oleg's code
* John Lato's cabalized [ package] of Oleg's code
* [[Iteratee I/O]]
* [[Iteratee I/O]]
* The Yesod book's [ appendix on the Enumerator package]

Revision as of 15:20, 10 October 2011

An enumerator is something that knows how to generate a list and an iteratee is something that does one step in processing another piece of the big list. E.g. to sum up all elements of a list, we do

foldl (+) 0 xs

Then foldl is the enumerator and ((+),0) is the iteratee.

Clearly the function that sums the current element with the accumulator, (+), doesn't know or care from which collection the elements are coming from. The initial seed, 0, is again unaware of the collection. That achieves the separation of concerns: fold (aka, enumerator) has the intimate knowledge of the collection and how to get to the next element; iteratee knows what to do with the current element.


1 Definition

Do not rely on the foldl analogy too firmly, it is misleading. ((+),0) is an F-algebra and foldl (+) 0 is a catamorphism. But iteratee is different, it is an automaton. From this point of view, the enumerator sends elements of a list sequentially, from head to tail, as input messages to the iteratee. If the iteratee finishes, it outputs an accumulator. If the iteratee continues, it outputs nothing (i.e., ()).

So, a set of states of iteratee is divided into subsets "Done" and "Next". Done-state means that automaton finished consuming a list, i.e., the automaton is dead. Next-state means that you can give an input message and obtain the same automaton in a new state.

data Iteratee i o
  = Done o
  | Next (i -> Iteratee i o)

i is the type of the iteratee's input messages (or list elements) and o is a type of the output message (an accumulator). Precisely speaking, Iteratee stores not an automaton, but an automaton in some state, an automaton with distinguished state. As you see, if an Iteratee is in the Next state, then we have a function that takes an input message and returns a new Iteratee.

The distinct feature of iteratee is that it can say after which list element an iteratee finishes. An iteratee says this by sending "Done" to an enumerator. Then the enumerator can, for example, close a file or a socket (a stream) where a list of characters is read from. Lazy I/O, which uses lazy lists, closes a stream only when the stream is exhausted.

The drawback is that an enumerator can not tell an iteratee that an input is exhausted — an Iteratee consumes only infinite lists. You can remedy this by assuming

i == Maybe i'

where i' is a type of list elements. Nothing given to iteratee signals that the list is exhausted.

Here is a sample enumerator that takes input messages from a file:

enumerator :: FilePath -> Iteratee (Maybe Char) o -> IO o
enumerator file it = withFile file ReadMode
  $ \h -> fix (\rc it -> case it of
    Done o -> return o
    Next f -> do
      eof <- hIsEOF h
      case eof of
        False -> do
          c <- hGetChar h
          rc (f (Just c))
        True -> rc (f Nothing)
    ) it

2 Functions

You can compose iteratees sequentially in time. This is done by (>>). it0 >> it1 means that when it0 finishes, it1 starts. Generally speaking, Iteratee i is a Monad, and it works exactly like a monadic parser.

{- s = state -}
instance Functor (Iteratee input) where
  fmap f = fix $ \rc s -> case s of
    Done o -> Done (f o)
    Next g -> Next (rc . g)
instance Monad (Iteratee input) where
  return = Done
  it0 >>= it1 = fix (\rc s -> case s of
    Done o -> it1 o
    Next g -> Next (rc . g)
    ) it0

You can also compose iteratees sequentially in space. it0's output messages become it1's input messages, so it0 and it1 work in parallel. Their composition is denoted it1 . it0. If it0 finishes, it is resurrected to its original state. If it1 finishes, it1 . it0 finishes — The main feature here is that it0 is restarted, as this is used for repetitive parsing.

arr0 f = Next $ \i -> Done (f i)
instance Category Iteratee where
  id = arr0 id
  it1 . it0 = fix (\rc1 it1 -> case it1 of
    Done c -> Done c
    Next f1 -> fix (\rc0 it0 -> case it0 of
      Done b -> rc1 (f1 b)
      Next f0 -> Next (rc0 . f0)
      ) it0
    ) it1

3 Generalization

You may note that Iteratee is final coalgebra. Other kinds of automata can be described with other F-coalgebras. In practice such automata can handle network protocols or interactive user input. See for example papers by Bart Jacobs for theoretical discussion.

4 See also