Personal tools

Existential type

From HaskellWiki

(Difference between revisions)
Jump to: navigation, search
m (A short example: added an explicit type signature)
Line 1: Line 1:
This is a extension of Haskell available in [[GHC]]. See the GHC documentation:
This is an extension of Haskell available in [[GHC]]. See the GHC documentation:
Line 242: Line 242:
===Cases that really require existentials===
===Cases that really require existentials===
There are cases where this sort of trick doesnt work. Here are two examples from a haskell mailing list discussion (from K. Claussen) that don't seem expressible without
There are cases where this sort of trick doesn't work. Here are two examples from a haskell mailing list discussion (from K. Claussen) that don't seem expressible without
existentials. (But maybe one can rethink the whole thing :)
existentials. (But maybe one can rethink the whole thing :)

Revision as of 19:53, 5 December 2008


This is an extension of Haskell available in GHC. See the GHC documentation:

1 Introduction to existential types

1.1 Overview

Normally when creating a new type using
, etc., every type variable that appears on the right-hand side must also appear on the left-hand side. Existential types are a way of turning this off.

1.2 Basics

Existential types can be used for several different purposes. But what they do is to 'hide' a type variable on the right-hand side.

Normally, any type variable appearing on the right must also appear on the left:

data Worker x y = Worker {buffer :: b, input :: x, output :: y}

This is an error, since the type of the buffer isn't specified on the right (it's a type variable rather than a type) but also isn't specified on the left (there's no 'b' in the left part). In Haskell98, you would have to write

data Worker b x y = Worker {buffer :: b, input :: x, output :: y}

That may or may not be an actual problem.

Usually there is no problem at all with this state of affairs (which is why Haskell98 works this way). However, suppose that a
can use any type 'b' so long as it belongs to some particular class. Then every function that uses a
will have a type like
foo :: (Buffer b) => Worker b Int Int

or something. (In particular, failing to write an explicit type signature will invoke the dreaded monomorphism restriction.) Using existential types, we can avoid this:

data Worker x y = forall b. Buffer b => Worker {buffer :: b, input :: x, output :: y}
foo :: Worker Int Int
The type of the buffer now does not appear in the
type at all. This has a number of consequences. First of all, it is now impossible for a function to demand a
having a specific type of buffer. Second, the type of
can now be derived automatically without needing an explicit type signature. (No monomorphism restriction.) Thirdly, since code now has no idea what type the
function returns, you are more limited in what you can do to it.

In general, when you use a 'hidden' type in this way, you will usually want that type to belong to a specific class, or you will want to pass some functions along that can work on that type. Otherwise you'll have some value belonging to a random unknown type, and you won't be able to do anything to it!

Note: You can use existential types to convert a more specific type into a less specific one. (See the examples below.) There is no way to perform the reverse conversion!

2 Examples

2.1 A short example

This illustrates creating a heterogeneous list, all of whose members implement "Show", and progressing through that list to show these items:

data Obj = forall a. (Show a) => Obj a
xs :: [Obj]
xs = [Obj 1, Obj "foo", Obj 'c']
doShow :: [Obj] -> String
doShow [] = ""
doShow ((Obj x):xs) = show x ++ doShow xs

With output: doShow xs ==> "1\"foo\"'c'"

2.2 Expanded example - rendering objects in a raytracer

2.2.1 Problem statement

In a raytracer, a requirement is to be able to render several different objects (like a ball, mesh or whatever). The first step is a type class for Renderable like so:

class Renderable a where
 boundingSphere :: a -> Sphere
 hit :: a -> [Fragment] -- returns the "fragments" of all hits with ray
{- ... etc ... -}
To solve the problem, the
function must apply to several objects (like a sphere and a polygon for instance).
hits :: Renderable a => [a] -> [Fragment]
hits xs = sortByDistance $ concatMap hit xs

However, this does not work as written since the elements of the list can be of SEVERAL different types (like a sphere and a polygon and a mesh etc. etc.) but lists need to have elements of the same type.

2.2.2 The solution

Use 'existential types' - an extension to Haskell that can be found in most compilers.

The following example is based on GHC :

  {-# OPTIONS -fglasgow-exts #-}
  {- ...-}
  data AnyRenderable = forall a. Renderable a => AnyRenderable a
  instance Renderable AnyRenderable where
      boundingSphere (AnyRenderable a) = boundingSphere a
      hit (AnyRenderable a) = hit a
  {-      ... -}
Now, create lists with type
, for example,
    [ AnyRenderable x
    , AnyRenderable y
    , AnyRenderable z ]
where x, y, z can be from different instances of

2.3 Dynamic dispatch mechanism of OOP

Existential types in conjunction with type classes can be used to emulate the dynamic dispatch mechanism of object oriented programming languages. To illustrate this concept I show how a classic example from object oriented programming can be encoded in Haskell.

 class Shape_ a where
   perimeter :: a -> Double
   area      :: a -> Double
 data Shape = forall a. Shape_ a => Shape a
 type Radius = Double
 type Side   = Double
 data Circle    = Circle    Radius
 data Rectangle = Rectangle Side Side
 data Square    = Square    Side
 instance Shape_ Circle where
   perimeter (Circle r) = 2 * pi * r
   area      (Circle r) = pi * r * r
 instance Shape_ Rectangle where
   perimeter (Rectangle x y) = 2*(x + y)
   area      (Rectangle x y) = x * y
 instance Shape_ Square where
   perimeter (Square s) = 4*s
   area      (Square s) = s*s
 instance Shape_ Shape where
   perimeter (Shape shape) = perimeter shape
   area      (Shape shape) = area      shape
 -- Smart constructor
 circle :: Radius -> Shape
 circle r = Shape (Circle r)
 rectangle :: Side -> Side -> Shape
 rectangle x y = Shape (Rectangle x y)
 square :: Side -> Shape
 square s = Shape (Square s)
 shapes :: [Shape]
 shapes = [circle 2.4, rectangle 3.1 4.4, square 2.1]

(You may see other Smart constructors for other purposes).

2.4 Generalised algebraic datatype

The type of the
function for this GADT is a good example to illustrate the concept of existential type.

3 Alternate methods

3.1 Concrete data types

3.1.1 Universal instance of a Class

Here one way to simulate existentials (Hawiki note: (Borrowed from somewhere...))

Suppose I have a type class Shape a

 type Point = (Float,Float)
 class Shape a  where
	draw :: a -> IO ()
	translate :: a-> Point -> a

Then we can pack shapes up into a concrete data type like this:

  data SHAPE = SHAPE (IO ()) (Point -> SHAPE)

with a function like this

  packShape :: Shape a => a -> SHAPE
  packShape s = SHAPE (draw s) (\(x,y) -> packShape (translate s (x,y)))

This would be useful if we needed a list of shapes that we would need to translate and draw.

In fact we can make
an instance of
  instance Shape SHAPE where
    draw (SHAPE d t) = d
    translate (SHAPE d t) = t

So SHAPE is a sort of universal instance.

3.1.2 Using constructors and combinators

Why bother with class
? Why not just go straight to
 data Shape = Shape {
    draw :: IO()
    translate :: (Int, Int) -> Shape

Then you can create a library of shape constructors and combinators that each have defined "draw" and "translate" in their "where" clauses.

 circle :: (Int, Int) -> Int -> Shape
 circle (x,y) r =
    Shape draw1 translate1
       draw1 = ...
       translate1 (x1,y1) = circle (x+x1, y+y1) r
 shapeGroup :: [Shape] -> Shape
 shapeGroup shapes = Shape draw1 translate1
       draw1 = sequence_ $ map draw shapes
       translate1 v = shapeGroup $ map (translate v) shapes

3.2 Cases that really require existentials

There are cases where this sort of trick doesn't work. Here are two examples from a haskell mailing list discussion (from K. Claussen) that don't seem expressible without existentials. (But maybe one can rethink the whole thing :)

  data Expr a = Val a | forall b . Apply (Expr (b -> a)) (Expr b)


  data Action = forall b . Act (IORef b) (b -> IO ())
(Maybe this last one could be done as a
type Act (IORef b) (IORef b -> IO ())
then we could hide the
as above, that is go ahead and apply the second argument to the first)

4 Examples from the Essential Haskell Compiler project

See the documentation on EHC, each paper at the Version 4 part:

  • Chapter 8 (EH4) of Atze Dijkstra's Essential Haskell PhD thesis (most recent version). A detailed explanation. It explains also that existential types can be expressed in Haskell, but their use is restricted to data declarations, and the notation (using keyword
    ) may be confusing. In Essential Haskell, existential types can occur not only in data declarations, and a separate keyword
    is used for their notation.
  • Essential Haskell Compiler overview
  • Examples

5 See also

5.1 Trac

Existential Quantification is a detailed material on the topic. It has link also to the smaller Existential Quantifier page.