Personal tools

Introduction to QuickCheck2

From HaskellWiki

(Difference between revisions)
Jump to: navigation, search
(Cloned the Introduction_to_QuickCheck page and adjusted the examples for QuickCheck 2)
 
m (Going further: updated the link “The QuickCheck source”)
 
(One intermediate revision by one user not shown)
Line 253: Line 253:
 
those you've seen here to be tested. Some sources for further reading
 
those you've seen here to be tested. Some sources for further reading
 
are:
 
are:
* [http://code.haskell.org/QuickCheck/stable/Test/ The QuickCheck source]
+
* [https://github.com/nick8325/quickcheck/tree/master/Test The QuickCheck source]
 
* [http://hackage.haskell.org/package/QuickCheck-2.4.2 QuickCheck Library documentation]
 
* [http://hackage.haskell.org/package/QuickCheck-2.4.2 QuickCheck Library documentation]
 
* [http://www.cse.chalmers.se/~rjmh/QuickCheck/manual.html QuickCheck v1 Manual]
 
* [http://www.cse.chalmers.se/~rjmh/QuickCheck/manual.html QuickCheck v1 Manual]
* [http://www.cse.unsw.edu.au/~dons/code/fps/tests/Properties.hs A large testsuite of QuickCheck code]
 
 
* Tutorial: [[QuickCheck as a test set generator]]
 
* Tutorial: [[QuickCheck as a test set generator]]
 
* Tutorial: [[QuickCheck / GADT]]
 
* Tutorial: [[QuickCheck / GADT]]

Latest revision as of 11:38, 28 November 2013

A quick introduction to QuickCheck2, and testing Haskell code.

Contents

[edit] 1 Motivation

In September 2006, Bruno Martínez asked the following question:

-- I've written a function that looks similar to this one
 
getList = find 5 where
     find 0 = return []
     find n = do
       ch <- getChar
       if ch `elem` ['a'..'e'] then do
             tl <- find (n-1)
             return (ch : tl) else
           find n
 
-- I want to test this function, without hitting the filesystem.  In C++ I
-- would use a istringstream.  I couldn't find a function that returns a
-- Handle from a String.  The closer thing that may work that I could find
-- was making a pipe and convertind the file descriptor.  Can I simplify
-- that function to take it out of the IO monad?

So the problem is: how to effectively test this function in Haskell? The solution we turn to is refactoring and QuickCheck.

[edit] 2 Keeping things pure

The reason your getList is hard to test, is that the side effecting monadic code is mixed in with the pure computation, making it difficult to test without moving entirely into a "black box" IO-based testing model. Such a mixture is not good for reasoning about code.

Let's untangle that, and then test the referentially transparent parts simply with QuickCheck. We can take advantage of lazy IO firstly, to avoid all the unpleasant low-level IO handling.

So the first step is to factor out the IO part of the function into a thin "skin" layer:

-- A thin monadic skin layer
getList :: IO [Char]
getList = fmap take5 getContents
 
-- The actual worker
take5 :: [Char] -> [Char]
take5 = take 5 . filter (`elem` ['a'..'e'])

[edit] 3 Testing with QuickCheck >=2.0

Now we can test the 'guts' of the algorithm, the take5 function, in isolation. Let's use QuickCheck. First we need an Arbitrary instance for the Char type -- this takes care of generating random Chars for us to test with. I'll restrict it to a range of nice chars just for simplicity:

import Data.Char
import Test.QuickCheck
 
-- Arbitrary Char is now part of the library
{-
instance Arbitrary Char where
    arbitrary     = choose ('\32', '\128')
    coarbitrary c = variant (ord c `rem` 4)
-}

Let's fire up GHCi (or Hugs) and try some generic properties (its nice that we can use the QuickCheck testing framework directly from the Haskell prompt). An easy one first, a [Char] is equal to itself:

*A> quickCheck ((\s -> s == s) :: [Char] -> Bool)
+++ OK, passed 100 tests.

What just happened? QuickCheck generated 100 random [Char] values, and applied our property, checking the result was True for all cases. QuickCheck generated the test sets for us!

A more interesting property now: reversing twice is the identity:

*A> quickCheck ((\s -> (reverse.reverse) s == s) :: [Char] -> Bool)
+++ OK, passed 100 tests.

Great!

[edit] 4 Testing take5

The first step to testing with QuickCheck is to work out some properties that are true of the function, for all inputs. That is, we need to find invariants.

A simple invariant might be:

   \forall~s~.~length~(take5~s)~=~5

So let's write that as a QuickCheck property:

\s -> length (take5 s) == 5

Which we can then run in QuickCheck as:

*A> quickCheck (\s -> length (take5 s) == 5)
*** Failed! Falsifiable (after 1 test):
""

Ah! QuickCheck caught us out. If the input string contains less than 5 filterable characters, the resulting string will be less than 5 characters long. So let's weaken the property a bit:

   \forall~s~.~length~(take5~s)~\le~5

That is, take5 returns a string of at most 5 characters long. Let's test this:

*A> quickCheck (\s -> length (take5 s) <= 5)
+++ OK, passed 100 tests.

Good!

[edit] 5 Another property

Another thing to check would be that the correct characters are returned. That is, for all returned characters, those characters are members of the set ['a','b','c','d','e'].

We can specify that as: \forall~s~.~\forall~e~.~e~\in~take5~s~\to~e~\in~[abcde]

And in QuickCheck:

*A> quickCheck (\s -> all (`elem` ['a'..'e']) (take5 s))
+++ OK, passed 100 tests.

Excellent. So we can have some confidence that the function neither returns strings that are too long, nor includes invalid characters.

[edit] 6 Coverage

One issue with the default QuickCheck configuration, when testing [Char], is that the standard 100 tests isn't enough for our situation. In fact, QuickCheck never generates a String greater than 5 characters long, when using the supplied Arbtrary instance for Char! We can confirm this:

*A> quickCheck (\s -> length (take5 s) < 5)
+++ OK, passed 100 tests.

QuickCheck wastes its time generating different Chars, when what we really need is longer strings. One solution to this is to modify QuickCheck's default configuration to test deeper:

deepCheck p = check (defaultConfig { configMaxTest = 10000}) p

This instructs the system to find at least 10000 test cases before concluding that all is well. Let's check that it is generating longer strings:

*A> deepCheck (\s -> length (take5 s) < 5)
*** Failed! Falsifiable (after 186 tests and 16 shrinks):
"aaaaa"

We can check the test data QuickCheck is generating using the 'verboseCheck' hook. Here, testing on integers lists:

*A> verboseCheck ((\s -> length s < 3) :: [Integer] -> Bool)
Passed:
[]
Passed:
[]
Passed:
[]
Passed:
[]
Failed:
[1,3,-4]
*** Failed! Passed:
[]
Passed:
[3,-4]
Passed:
[1,-4]
Passed:
[1,3]
Failed:
[0,3,-4]
Passed:
[]
Passed:
[3,-4]
Passed:
[0,-4]
Passed:
[0,3]
Failed:
[0,0,-4]
Passed:
[]
Passed:
[0,-4]
Passed:
[0,-4]
Passed:
[0,0]
Failed:
[0,0,4]
Passed:
[]
Passed:
[0,4]
Passed:
[0,4]
Passed:
[0,0]
Failed:
[0,0,0]
Passed:
[]
Passed:
[0,0]
Passed:
[0,0]
Passed:
[0,0]
Falsifiable (after 5 tests and 4 shrinks):
[0,0,0]
-- Need to add in an overview of the shrink process.

[edit] 7 Going further

QuickCheck is effectively an embedded domain specific language for testing Haskell code, and allows for much more complex properties than those you've seen here to be tested. Some sources for further reading are:

Note, QuickCheck doesn't need to just be an embedded domain specific language for testing Haskell code. By making instances of Arbitrary for FFI types you can use Haskell and QuickCheck to check code in other languages.