Keywords

From HaskellWiki

Revision as of 15:50, 19 February 2010

This page lists all Haskell keywords, feel free to edit. Hoogle searches will return results from this page. Please respect the Anchor macros.

For additional information you might want to look at the Haskell 98 report.

1 .

The dot "." is used to compose functions in point-free style, similar to "$".

foo = h . g . f

is the same as

foo x = h $ g $ f x

which is the same as

foo x = h (g (f x))

2 `

A function enclosed in back ticks "`" can be used as an infix operator.

2 `subtract` 10

is the same as

subtract 2 10

3 |

The "pipe" is used in several places

• Data type definitions, "or"

data Maybe a = Just a | Nothing

• List comprehensions, "where"

squares = [a*a | a <- [1..]]

• Guards, "when"

safeTail x | null x    = []
           | otherwise = tail x

• Functional dependencies

-- This examples assumes that each type 'c' can "contain" only one type
class Contains c elt | c -> elt where
   ...

4 \

The baskslash "\" is used to define multiline strings and lambda functions.

5 -

This operator token is magic/irregular in the sense that

(- 1)

is parsed as the negative integer -1, rather than as an operator section, as it would be for any other operator:

(* 1) :: Num a => a -> a

(++ "foo") :: String -> String

6 --

--this is a comment
---this too
x--+this_is_the_second_argument_of_the_dash_dash_plus_operator

7 -<

Arrow notation

8 -<<

Arrow notation

9 ->

• The function type constructor:

length :: [a] -> Int

• In lambdas:

\x -> x + 1

• To denote alternatives in case statements:

case Just 3 of
    Nothing -> False
    Just x  -> True

• On the kind level (GHC specific):

(->) :: ?? -> ? -> *

• Functional dependencies

-- This examples assumes that each type 'c' can "contain" only one type
class Contains c elt | c -> elt where
   ...

10 <-

In do-notation, "draw from":

do x <- getChar
   putChar x

In list comprehension generators, "is drawn from":

[ (x,y) | x <- [1..10], y <- ['a'..'z'] ]

In pattern guards, "matches":

f x y | Just z <- g x = True
      | otherwise     = False

11 @

Patterns of the form var@pat are called as-patterns, and allow one to use var as a name for the value being matched by pat. For example:

case e of { xs@(x:rest) -> if x==0 then rest else xs }

is equivalent to:

let { xs = e } in
   case xs of { (x:rest) -> if x==0 then rest else xs }

12 $

The dollar sign "$" is a way to compose functions, without typing too many brackets.

foo x = h $ g $ f x

is the same as

foo x = h (g (f x))

13  !

Whenever a data constructor is applied, each argument to the constructor is evaluated if and only if the corresponding type in the algebraic datatype declaration has a strictness flag, denoted by an exclamation point. For example:

data STList a 
         = STCons a !(STList a)  -- the second argument to STCons will be 
                                 -- evaluated before STCons is applied
         | STNil

to illustrate the difference between strict versus lazy constructor application, consider the following:

stList = STCons 1 undefined
 lzList = (:)    1 undefined
 stHead (STCons h _) = h -- this evaluates to undefined when applied to stList
 lzHead (h : _)      = h -- this evaluates to 1 when applied to lzList

! is also used in the "bang patterns" (GHC extension), to indicate strictness in patterns:

f !x !y = x + y

Finally, it is the array subscript operator:

let x = arr ! 10

14  :

The colon ":" is an infix operator that adds an element to the beginning of a list.

1 : [2,3]

will result in the new list

[1,2,3]

15  ::

Read as "has type":

length :: [a] -> Int

"Length has type list-of-'a' to Int"

16 _

Patterns of the form _ are wildcards and are useful when some part of a pattern is not referenced on the right-hand-side. It is as if an identifier not used elsewhere were put in its place. For example,

case e of { [x,_,_]  ->  if x==0 then True else False }

is equivalent to:

case e of { [x,y,z]  ->  if x==0 then True else False }

17 ~

Lazy pattern bindings. Matching the pattern ~pat against a value always suceeds, and matching will only diverge when one of the variables bound in the pattern is used.

f1,f2 :: Maybe Int -> String;
(+++),(++++) :: (a->b)->(c->d)->(a,c)->(b,d);
 
f1 x = case x of {Just n -> "Got it"};
f2 x = case x of {~(Just n) -> "Got it"};
 
(f +++ g) ~(x,y) = (f x , g y);
(f ++++ g) (x,y) = (f x , g y);

Then we have:

f1 Nothing
Exception: Non-exhaustive patterns in case
 
f2 Nothing
"Got it"
 
(const 1 +++ const 2) undefined
(1,2)
 
(const 1 ++++ const 2) undefined
Exception: Prelude.undefined

For more details see the Haskell Wikibook.

18 --

main = print "hello world" -- comment here

19 >

In a Bird's style Literate Haskell file, the > character is used to introduce a code line.

comment line
 
> main = print "hello world"

20 {, }

• Explicit block (disable layout)

• Record update notation

changePrice :: Thing -> Price -> Thing
changePrice x new = x { price = new }

• Comments (see below)

21 {-, -}

Multiline comment

{-
hello
world
-}

22  ;

• Statement separator in an explicit block (see layout)

23 as

import qualified Data.Map as M
 
main = print (M.empty :: M.Map Int ())

24 case, of

A case expression has the general form

case e of { p1 match1 ; ... ; pn matchn }

where each match_i is of the general form

| g1 -> e1
    ...
  | gm -> em
     where decls

Each alternative consists of patterns p_i and their matches, match_i. Each match_i in turn consists of a sequence of pairs of guards g_ij and bodies e_ij (expressions), followed by optional bindings (decls_i) that scope over all of the guards and expressions of the alternative. An alternative of the form

pat -> exp where decls

is treated as shorthand for:

pat | True -> exp
    where decls

A case expression must have at least one alternative and each alternative must have at least one body. Each body must have the same type, and the type of the whole expression is that type.

A case expression is evaluated by pattern matching the expression e against the individual alternatives. The alternatives are tried sequentially, from top to bottom. If e matches the pattern in the alternative, the guards for that alternative are tried sequentially from top to bottom, in the environment of the case expression extended first by the bindings created during the matching of the pattern, and then by the decls_i  in the where clause associated with that alternative. If one of the guards evaluates to True, the corresponding right-hand side is evaluated in the same environment as the guard. If all the guards evaluate to False, matching continues with the next alternative. If no match succeeds, the result is _|_.

25 class

A class declaration introduces a new type class and the overloaded operations that must be supported by any type that is an instance of that class.

class Num a  where
    (+)    :: a -> a -> a
    negate :: a -> a

26 data

The data declaration is how one introduces new algebraic data types into Haskell. For example:

data Set a = NilSet 
           | ConsSet a (Set a)

Another example, to create a datatype to hold an abstract syntax tree for an expression, one could use:

data Exp = Ebin   Operator Exp Exp 
          | Eunary Operator Exp 
          | Efun   FunctionIdentifier [Exp] 
          | Eid    SimpleIdentifier

where the types Operator, FunctionIdentifier and SimpleIdentifier are defined elsewhere.

See the page on types for more information, links and examples.

27 data family

Declares a datatype family (see type families). GHC language extension.

28 data instance

Declares a datatype family instance (see type families). GHC language extension.

29 default

Ambiguities in the class Num are most common, so Haskell provides a way to resolve them---with a default declaration:

default (Int)

Only one default declaration is permitted per module, and its effect is limited to that module. If no default declaration is given in a module then it assumed to be:

default (Integer, Double)

30 deriving

data and newtype declarations contain an optional deriving form. If the form is included, then derived instance declarations are automatically generated for the datatype in each of the named classes.

Derived instances provide convenient commonly-used operations for user-defined datatypes. For example, derived instances for datatypes in the class Eq define the operations == and /=, freeing the programmer from the need to define them.

data T = A
       | B
       | C
       deriving (Eq, Ord, Show)

In the case of newtypes, GHC extends this mechanism to Cunning Newtype Deriving.

31 deriving instance

Standalone deriving (GHC language extension).

{-# LANGUAGE StandaloneDeriving #-}
data A = A
 
deriving instance Show A

32 do

Syntactic sugar for use with monadic expressions. For example:

do { x ; result <- y ; foo result }

is shorthand for:

x >> 
 y >>= \result ->
 foo result

33 forall

This is a GHC/Hugs extension, and as such is not portable Haskell 98. It is only a reserved word within types.

Type variables in a Haskell type expression are all assumed to be universally quantified; there is no explicit syntax for universal quantification, in standard Haskell 98. For example, the type expression

For clarity, however, we often write quantification explicitly when discussing the types of Haskell programs. When we write an explicitly quantified type, the scope of the forall extends as far to the right as possible; for example,

forall a. a -> a

means

forall a. (a -> a)

existential types:

data Foo = forall a. MkFoo a (a -> Bool)
         | Nil
 
MkFoo :: forall a. a -> (a -> Bool) -> Foo
Nil   :: Foo
 
[MkFoo 3 even, MkFoo 'c' isUpper] :: [Foo]

34 foreign

35 hiding

When importing modules, without introducing a name into scope, entities can be excluded by using the form

hiding (import1 , ... , importn )

which specifies that all entities exported by the named module should be imported except for those named in the list.

For example:

import Prelude hiding (lookup,filter,foldr,foldl,null,map)

36 if, then, else

A conditional expression has the form:

if e1 then e2 else e3

and returns the value of e2 if the value of e1 is True, e3 if e1 is False, and _|_ otherwise.

max a b = if a > b then a else b

37 import

Modules may reference other modules via explicit import declarations, each giving the name of a module to be imported and specifying its entities to be imported.

For example:

module Main where
    import A
    import B
    main = A.f >> B.f
 
  module A where
    f = ...
 
  module B where
    f = ...

See also as, hiding , qualified and the page Import

38 infix, infixl, infixr

A fixity declaration gives the fixity and binding precedence of one or more operators. The integer in a fixity declaration must be in the range 0 to 9. A fixity declaration may appear anywhere that a type signature appears and, like a type signature, declares a property of a particular operator.

There are three kinds of fixity, non-, left- and right-associativity (infix, infixl, and infixr, respectively), and ten precedence levels, 0 to 9 inclusive (level 0 binds least tightly, and level 9 binds most tightly).

module Bar where
    infixr 7 `op`
    op = ...

39 instance

An instance declaration declares that a type is an instance of a class and includes the definitions of the overloaded operations - called class methods - instantiated on the named type.

instance Num Int  where
    x + y       =  addInt x y
    negate x    =  negateInt x

40 let, in

Let expressions have the general form:

let { d1 ; ... ; dn } in e

They introduce a nested, lexically-scoped, mutually-recursive list of declarations (let is often called letrec in other languages). The scope of the declarations is the expression e and the right hand side of the declarations.

41 mdo

42 module

Taken from: A Gentle Introduction to Haskell, Version 98

Technically speaking, a module is really just one big declaration which begins with the keyword module; here's an example for a module whose name is Tree:

module Tree ( Tree(Leaf,Branch), fringe ) where
 
data Tree a                = Leaf a | Branch (Tree a) (Tree a) 
 
fringe :: Tree a -> [a]
fringe (Leaf x)            = [x]
fringe (Branch left right) = fringe left ++ fringe right

43 newtype

The newtype declaration is how one introduces a renaming for an algebraic data type into Haskell. This is different from type below, as a newtype requires a new constructor as well. As an example, when writing a compiler one sometimes further qualifies Identifiers to assist in type safety checks:

newtype SimpleIdentifier = SimpleIdentifier Identifier
newtype FunctionIdentifier = FunctionIdentifier Identifier

Most often, one supplies smart constructors and destructors for these to ease working with them.

See the page on types for more information, links and examples.

For the differences between newtype and data, see Newtype.

44 proc

Arrow notation

45 qualified

Used to import a module, but not introduce a name into scope. For example, Data.Map exports lookup, which would clash with the Prelude version of lookup, to fix this:

import qualified Data.Map
 
f x = lookup x -- use the Prelude version
g x = Data.Map.lookup x -- use the Data.Map version

Of course, Data.Map is a bit of a mouthful, so qualified also allows the use of as.

import qualified Data.Map as M
 
f x = lookup x -- use Prelude version
g x = M.lookup x -- use Data.Map version

46 rec

The rec keyword can be used when the -XDoRec flag is given; it allows recursive bindings in a do-block.

{-# LANGUAGE DoRec #-}
justOnes = do { rec { xs <- Just (1:xs) }
              ; return (map negate xs) }

47 type

The type declaration is how one introduces an alias for an algebraic data type into Haskell. As an example, when writing a compiler one often creates an alias for identifiers:

type Identifier = String

This allows you to use Identifer wherever you had used String and if something is of type Identifier it may be used wherever a String is expected.

See the page on types for more information, links and examples.

Some common type declarations in the Prelude include:

type FilePath = String
type String = [Char]
type Rational = Ratio Integer
type ReadS a = String -> [(a,String)]
type ShowS = String -> String

48 type family

Declares a type synonym family (see type families). GHC language extension.

49 type instance

Declares a type synonym family instance (see type families). GHC language extension.

50 where

Used to introduce a module, instance or class:

module Main where
 
class Num a where
    ...
 
instance Num Int  where
    ...

And to bind local variables:

f x = y
    where y = x * 2
 
g z | z > 2 = y
    where y = x * 2

Category: Language