Parameter order

From HaskellWiki

The parameter order of Haskell functions is an important design decision when programming libraries. The parameter order shall

• allow piping,
• be consistent across similar functions.

Parameters in Haskell are rather reversed compared to imperative or object oriented languages. In an object oriented language, the object to work on is the very first parameter. In a function call it is often written even before the function name, say file in file.write("bla"). Strictly spoken, in Haskell it is not possible to alter objects, but there are many functions which return a somehow altered input object. This object should be the last parameter because then you can compose a sequence of operations on this object

The code

sum . map f . filter p . scanl (*) 1

describes a function, which applies three transformations to a list. This can be written so easily because the list is always the last parameter.

The order of the parameters except the last one is not so critical. However you should keep in mind that also transformations on functions are perfectly ok in Haskell. That's why function operators like the differentiation and integration in functional analysis should have the parameter of the derived/integrated function at the last position and the transformed function should be the parameter before the last one.

integrate :: a -> (a -> a) -> (a -> a)
integrate f0 f x = ...
 
differentiate :: a -> (a -> a) -> (a -> a)
differentiate h f x = ...
 
-- continuous extension, aka function limit
continuous :: (a -> a) -> (a -> a)
continuous f x = ...
 
exampleTransform = differentiate h . continuous

The third thing to consider is that it is easily possible to fix parameters, which are at the beginning. E.g.

sum = foldl (+) 0
product = foldl (*) 1

We also see in this example that it is easily possible to generate a function with the first parameters fixed and that functions shall be prepared for this.

Also for the implementation of a function the order of parameters count.

a carefully chosen parameter order simplifies the implementation, and this one should also be prefered. Say, you want to know which of the signatures

printMsg :: String -> Maybe Int -> String
printMsg :: Maybe Int -> String -> String

shall be used. The implementation might be

printMsg :: String -> Maybe Int -> String
printMsg msg Nothing  = msg ++ "\n"
printMsg msg (Just n) = msg ++ " " ++ show n ++ "\n"

printMsg :: String -> Maybe Int -> String
printMsg msg mn =
   msg ++
     (case mn of
        Nothing -> ""
        Just n  -> " " ++ show n) ++
   "\n"

Even shorter:

printMsg :: String -> Maybe Int -> String
printMsg msg mn =
   msg ++ maybe "" (\n -> " " ++ show n) mn ++ "\n"

1 Bad examples

Sometimes library writers have infix usage of functions in mind.

Unfortunately the order of arguments to infix operators, which seems to be natural for many programmers, is reversed with respect to the one we encourage above. Maybe this only indicates that parameter order should be reverse, at all, meaning that the name of the called function comes after the arguments (Reverse Polish Notation).

However when using section, in most cases the first argument is omitted. This strongly indicates that their parameter order is unnatural in the Haskell sense.

There are more cases where there is even no simple reason, why the parameter order was chosen in an unnatural way.

• Data.Map.lookup :: (Monad m, Ord k) => k -> Map k a -> m a
• Data.Map.findWithDefault :: Ord k => a -> k -> Map k a -> a
• Data.Map.lookupIndex :: (Monad m, Ord k) => k -> Map k a -> m Int
• Data.Map.findIndex :: Ord k => k -> Map k a -> Int

All of the functions above do this in some way,

flip (Data.Map.findWithDefault deflt) :: Ord k => Map k a -> (k -> a)

Unfortunately the parameters are ordered in a way that requires a flip for revealing this connection.

2 Context

Say a set of your functions works within a certain context. You have a function which run these functions within that context.

startSound :: (SoundServer -> IO a) -> IO a

Since a context is something that varies not very frequently it should be the first parameter.

play :: SoundServer -> Sound -> IO ()

This way it is easy to play a sequence of sounds, say

startSound (\server -> mapM_ (play server) [soundA, soundB, soundC])   .

On the other hand the parameter order

play' :: Sound -> SoundServer -> IO ()

simplifies the calls to single sound functions:

startSound (play' soundA)    .

In this case we should actually make the context the last argument, but hide it in a Reader monad.

type SoundAction a = ReaderT SoundServer IO a
 
playM :: Sound -> SoundAction ()
playM = ReaderT . play'
 
startSoundM :: SoundAction a -> IO a
startSoundM = startSound . runReaderT

This way, both of the above examples become equally simple.

startSoundM (mapM_ playM [soundA, soundB, soundC])
startSoundM (playM soundA)

3 The rule of thumb

What do we learn from all this considerations?

The more important the parameter, the more frequently it changes, the closer shall it be at the end of the parameter list. If there is some recursion involved, probably the parameter, on which you recurse, is the one which should be at the last position.

Category: Style