Phooey

From HaskellWiki

(Difference between revisions)

Revision as of 04:15, 11 September 2007

1 Abstract
2 Introduction
3 One example, two interfaces
- 3.1 Monad
- 3.2 Applicative Functor
4 Layout
5 Event Examples
- 5.1 Counting
- 5.2 Calculator
6 Portability
7 Known problems
8 Plans

1 Abstract

Warning: The Haddock docs are not ready yet. I'm trying to get a working haddock 2.0 running (on my windows machine).

Phooey is a functional UI library for Haskell. Or it's two of them, as it provides a

Monad

interface and an

Applicative

interface. The simplicity of Phooey's implementation is due to its use of DataDriven for applicative, data-driven computation.

Besides this wiki page, here are more ways to find out about Phooey:

Read the Haddock docs (with source code, additional examples, and Comment/Talk links).
Get the code repository: darcs get http://darcs.haskell.org/packages/phooey, or
Grab a distribution tarball.
See the version changes.

Phooey is also used in GuiTV, a library for composable interfaces and "tangible values".

2 Introduction

GUIs are usually programmed in an unnatural style, in that implementation dependencies are inverted, relative to logical dependencies. This reversal results directly from the push (data-driven) orientation of most GUI libraries. While outputs depend on inputs from a user and semantic point of view, the push style imposes an implementation dependence of inputs on outputs.

A second drawback of the push style is that it is imperative rather than declarative. A GUI program describes actions to update a model and and view in reaction to user input. In contrast to the how-to-update style of an imperative program, a functional GUI program would express what-it-is of a model in terms of the inputs and of the view in terms of the model.

The questions of push-vs-pull and imperative-vs-declarative are related. While an imperative GUI program could certainly be written to pull (poll) values from input to model and model to view, thus eliminating the dependency inversion, I don't know how a declarative program could be written in the inverted-dependency style. (Do you?).

A important reason for using push rather than pull in a GUI implementation is that push is typically much more efficient. A simple pull implementation would either waste time recomputing an unchanging model and view (pegging your CPU for no benefit), or deal with the complexity of avoiding that recomputation. The push style computes only when inputs change. (Continuous change, i.e. animation, negates this advantage of push.)

Phooey ("Phunctional ooser ynterfaces") adopts the declarative style, in which outputs are expressed in terms of inputs. Under the hood, however, the implementation is push-based (data-driven). Phooey uses the DataDriven library to perform the dependency inversion invisibly, so that programmers may express GUIs simply and declaratively while still getting an efficient implementation.

Phooey came out of Pajama and Eros. Pajama is a re-implementation of the Pan language and compiler for function synthesis of interactive, continuous, infinite images. Pan and Pajama use a monadic style for specifying GUIs and are able to do so because they use the implementation trick of Compiling Embedded Languages, in which one manipulates expressions rather than values. (This trick is mostly transparent, but the illusion shows through in places.)

3 One example, two interfaces

As an example, below is a simple shopping list GUI. The

total

displayed at the bottom of the window always shows the sum of the values of the

apples

and

bananas

input sliders. When a user changes the inputs, the output updates accordingly.

Phooey presents two styles of functional GUI interfaces, structured as a monad and as an applicative functor. (I have removed the original arrow interface.) Below you can see the code for the shopping list example in each of these styles.

The examples below are all found under src/Examples/ in the phooey distribution, in the modules Monad.hs, and Applicative.hs. In each case, the example is run by loading the corresponding example module into ghci and typing

runUI ui1

3.1 Monad

Here is a definition for the GUI shown above, formulated in terms of Phooey's monadic interface. See the monad interface and its source code.

ui1 :: UI ()
ui1 = title "Shopping List" $
      do a <- title "apples"  $ islider (0,10) 3
         b <- title "bananas" $ islider (0,10) 7
         title "total" $ showDisplay (liftA2 (+) a b)

The relevant library declarations:

-- Input widget type (with initial value)
type IWidget  a =        a -> UI (Source a)
-- Output widget type
type OWidget  a = Source a -> UI ()
 
islider     :: (Int,Int) -> IWidget Int
showDisplay :: Show a => OWidget a
title       :: String -> UI a -> UI a

The <div class="inline-code">

Source

</div> type is a (data-driven) source of time-varying values. By using

Source Int

instead of

Int

for the type of

a

and

b

above, we do not have to rebuild the GUI every time an input value changes. The down side of using source types is seen in the

showDisplay

line above, which requires lifting. We could partially hide the lifting behind overloadings of

Num

and other classes (as in Fran, Pan, and other systems). Some methods, however, do not not have sufficiently flexible types (e.g.,

(==)

), and the illusion becomes awkward. The

Arrow

and

Applicative

interfaces hide the source types.

Before we move on to other interface styles, let's look at some refactorings. First pull out the slider minus initial value:

sl0 :: IWidget Int
sl0 = islider (0,10)

Then the titled widgets:

apples, bananas :: UI (Source Int)
apples  = title "apples"  $ sl0 3
bananas = title "bananas" $ sl0 7
 
total :: Num a => OWidget a
total = title "total" . showDisplay

And use them:

ui1x :: UI ()
ui1x = title "Shopping List" $
       do a <- apples
          b <- bananas
          total (liftA2 (+) a b)

We can go point-free by using

liftM2

and

(>>=)

-- Sum UIs
infixl 6  .+.
 
(.+.) :: Num a => UIS a -> UIS a -> UIS a
(.+.) = liftA2 (liftA2 (+))
 
fruit :: UI (Source Int)
fruit = apples .+. bananas
 
ui1y :: UI ()
ui1y = title "Shopping List" $ fruit >>= total

3.2 Applicative Functor

Applicative functors (AFs) provide still another approach to separating static and dynamic information. Here is our example, showing just the changes relative to the monadic version. (See the Applicative interface doc and its source code.)

ui1 :: UI (IO ())
ui1 = title "Shopping List" $ fruit <**> total
 
fruit :: UI Int
fruit = liftA2 (+) apples bananas
 
total :: Num a => OWidget a
total = title "total" showDisplay

I chose reversed AF application

(<**>)

rather than

(<*>)

so the fruit (argument) would be displayed above the total (function).

The UI-building functions again have the same types as before, relative to these new definitions:

type IWidget a = a -> UI a
type OWidget a = UI (a -> IO ())

Notes:

Output widgets are function-valued UI.
fruit
has a simpler definition, requiring only one lifting instead of two.
total
is subtly different, because output widgets are now function-valued.
ui1
uses the reverse application operator
(<**>)
. This reversal causes the function to appear after (below) the argument.
ui1
is an IO-valued UI.

The applicative UI interface (

Graphics.UI.Phooey.Applicative

) is implemented as a very simple layer on top of the monadic interface, using type composition (from TypeCompose):

type UI = M.UI `O` Source

Thanks to properties of

O

, this definition suffices to make

UI

an AF.

4 Layout

By default, UI layout follows the order of the specification, with earlier-specified components above later-specified ones. This layout may be overridden by explicit layout functions. For instance, the following definitions form variations of

ui1

laid out from bottom to top and from left to right.

GUIs & code:

uiB1 = fromBottom ui1
uiL1 = fromLeft   ui1

We can also lay out a sub-assembly, as in

ui3

below

ui3 = fromBottom $
      title "Shopping  List" $
      fromRight fruit >>= total

5 Event Examples

The shopping examples above demonstrate the simple case of outputs (

total

) as functions of varying inputs (

apples

and

bananas

). Events were hidden inside the implementation of sources.

This section shows two classic functional GUI examples involving a visible notion of events.

5.1 Counting

5.2 Calculator

6 Portability

Phooey is built on wxHaskell. Quoting from the wxHaskell home page,

wxHaskell is therefore built on top of wxWidgets -- a comprehensive C++ library that is portable across all major GUI platforms; including GTK, Windows, X11, and MacOS X.

So I expect that Phooey runs on all of these platforms. That said, I have only tried Phooey on Windows. Please give it a try and leave a message on the talk page.

7 Known problems

Recursive examples don't work (consumes memory) in the Arrow or Applicative interface.

8 Plans

Use Javascript and HTML in place wxHaskell, and hook it up with Yhc/Javascript.

Retrieved from "http://www.haskell.org/haskellwiki/Phooey"

Categories: User interfaces | Arrow | Monad | Libraries | Packages

Personal tools

Views