pkgname=('haskell-dataenc' 'haskell-dataenc-doc')
pkgbase='dataenc'
pkgrel=2
pkgver=0.13.0.0
pkgdesc="Data encoding library"
url="http://hackage.haskell.org/cgi-bin/hackage-scripts/package/dataenc"
license=('custom:BSD3')
arch=('i686' 'x86_64')
depends=('ghc' 'haskell-cabal')
options=('strip')
source=(http://hackage.haskell.org/packages/archive/dataenc/0.13.0.0/dataenc-0.13.0.0.tar.gz)
md5sums=('97ef7f138465dcc9d27933badb785b87')

build() {
    cd $srcdir/dataenc-0.13.0.0

    # build source
    runhaskell Setup configure --prefix=/usr --htmldir=/usr/share/doc/ghc/libraries/\$pkg || return 1
    runhaskell Setup build                   || return 1

    # generate (un)register scripts
    runhaskell Setup register   --gen-script || return 1
    runhaskell Setup unregister --gen-script || return 1

    # generate documentation
    runhaskell Setup haddock || return 1
}

package_haskell-dataenc() {
    install=haskell-dataenc.install

    cd $srcdir/dataenc-0.13.0.0
    install -D -m744 register.sh   $pkgdir/usr/share/haskell/$pkgname/register.sh
    install    -m744 unregister.sh $pkgdir/usr/share/haskell/$pkgname/unregister.sh
    runhaskell Setup copy --destdir=$pkgdir || return 1
    install -D -m644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE || return 1

    # clean out docs
    rm -rf $pkgdir/usr/share/doc
}

package_haskell-dataenc-doc() {
    install=haskell-dataenc-doc.install

    cd $srcdir/dataenc-0.13.0.0
    runhaskell Setup copy --destdir=$pkgdir || return 1

    # clean out binaries
    rm -rf $pkgdir/usr/lib $pkgdir/usr/share/haskell
    rm -rf $pkgdir/usr/share/doc/$pkgbase-$pkgver
}